Вот пример скрипта на Inno Setup;
синим отмечено то, что обязательно поменять;
зелёным - меняете под себя (или удалите, если строчка выделена полностью), всё остальное - уже полностью на Ваше усмотрение.
[Setup]
// Картинка сбоку (разрешение: 164x314).
WizardImageFile=C:\Installers\CS\big_logo.bmp
// Картинка справа в углу (разрешение: 55x55).
WizardSmallImageFile=C:\Installers\CS\small_logo.bmp
// Значок установщика.
SetupIconFile=C:\Installers\CS\icon.ico
// Минимальная версия поддерживаемой ОС [WinXP без SP]; можно удалить.
MinVersion=0,5.01
// Непрерывный архив; лучшее сжатие, но больше времени компиляции.
SolidCompression=True
// Внешнее сжатие [максимальное].
Compression=lzma/ultra64
// Внутреннее сжатие [максимальное].
InternalCompressLevel=ultra
// Кол-во используемых ядер для компрессии.
CompressionThreads=auto
// Директория, куда будет сохранён установщик.
OutputDir=C:\
// Имя будущего установщика.
OutputBaseFilename=Setup
// Отображаемое имя в списке установленных программ (Панель Управления).
UninstallDisplayName=Counter-Strike 1.6
// Идентификатор установщика (генерируется вручную в Inno Script Studio).
AppId={{BF29033B-6C32-458E-906C-BEC1620044C4}
// Использование параметров от предыщущей установки:
// 1. Язык,
// 2. Тип установки (полный/выборочный),
// 3. Путь/директория установки,
// 4. Имя программной группы (в меню Пуск),
// 5. Задачи (создать ярлык на Рабочем столе или нет).
UsePreviousLanguage=False
UsePreviousSetupType=False
UsePreviousAppDir=False
UsePreviousGroup=False
UsePreviousTasks=False
// Путь директория установки по умолчанию ({pf} - Program Files).
DefaultDirName={pf}\Counter-Strike
// Имя программной группы (в меню Пуск).
DefaultGroupName=Counter-Strike
// Название программы.
AppName=Counter-Strike 1.6
// Номер версии (можно прописать билд).
AppVersion=4554
// Организация,
// Авторские права.
AppPublisher=CSmania.RU
AppCopyright=weinstreizeR
// Создание файла деинсталляции.
Uninstallable=yes
// Отображение в списке установленных программ, для удаления.
CreateUninstallRegKey=yes
// При установке программы:
// 1. Закрывать другие приложения,
// 2. Перезапустить другие приложения.
CloseApplications=False
RestartApplications=False
// После удаления программы требовать перезагрузку ПК?
RestartIfNeededByRun=False
// Языковые параметры [настроено для использования одного языка]:
// 1. Отображение диалога выбора языков,
// 2. Определение языка [отключено].
ShowLanguageDialog=no
LanguageDetectionMethod=none
// Разрешить показывать на странице готовности к установке:
// 1. Выбранную программную группу,
// 2. Выбранные путь и директорию установки.
AlwaysShowGroupOnReadyPage=True
AlwaysShowDirOnReadyPage=True
// Разрешить не создавать ярлыки в меню Пуск.
AllowNoIcons=True
[Languages]
// Используемый язык установщика; путь к файлу с лиц. соглащением.
Name: "Russian"; MessagesFile: "compiler:Languages\Russian.isl"; LicenseFile: "C:\Installers\CS\license.txt"
[UninstallDelete]
// После удаления программы удаляются оставшиеся файлы и папки (включая корневую).
Type: filesandordirs; Name: "{app}"
[Tasks]
// Задача: добавляется страница, где можно выбрать, создавать ярлык(и) на Рабочем столе или нет.
Name: "DesktopIcon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"
[Types]
// Типы установки.
Name: "Full"; Description: "Полная установка"
Name: "Custom"; Description: "Выборочная установка"; Flags: iscustom
[Components]
// Выбор компонентов установки: 1. Игра; 2. Опциональные компоненты (если компонентов много - удалите лишнее).
Name: "CS"; Description: "Counter-Strike"; Types: Full Custom; Flags: checkablealone fixed disablenouninstallwarning
Name: "Component1"; Description: "Component 1"; Types: Full; Flags: dontinheritcheck
Name: "Component2"; Description: "Component 2"; Types: Full; Flags: dontinheritcheck
Name: "Component3"; Description: "Component 3"; Types: Full; Flags: dontinheritcheck
Name: "Component4"; Description: "Component 4"; Types: Full; Flags: dontinheritcheck
Name: "Component5"; Description: "Component 5"; Types: Full; Flags: dontinheritcheck
Name: "Component6"; Description: "Component 6"; Types: Full; Flags: dontinheritcheck
Name: "Component7"; Description: "Component 7"; Types: Full; Flags: dontinheritcheck
Name: "Component8"; Description: "Component 8"; Types: Full; Flags: dontinheritcheck
Name: "Component9"; Description: "Component 9"; Types: Full; Flags: dontinheritcheck
[Files]
// Расположение файлов игры и опциональных компонентов.
Source: "C:\Installers\CS\Client\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: CS
Source: "C:\Installers\CS\Component1\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component1
Source: "C:\Installers\CS\Component2\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component2
Source: "C:\Installers\CS\Component3\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component3
Source: "C:\Installers\CS\Component4\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component4
Source: "C:\Installers\CS\Component5\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component5
Source: "C:\Installers\CS\Component6\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component6
Source: "C:\Installers\CS\Component7\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component7
Source: "C:\Installers\CS\Component8\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component8
Source: "C:\Installers\CS\Component9\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Component9
[Run]
// В конце установки будет показана страница с чекбоксом "Запустить <приложение>".
Filename: "{app}\Run_CS.exe"; WorkingDir: "{app}"; Flags: nowait postinstall; Description: "{cm:LaunchProgram,Counter-Strike}"; Tasks: DesktopIcon
[Icons]
// Создание ярлыков: 1. Ярлык игры - Рабочий стол; 2. Ярлык игры - в меню Пуск; Деинсталляция - в меню Пуск.
Name: "{userdesktop}\Counter-Strike"; Filename: "{app}\Run_CS.exe"; IconFilename: "{app}\Run_CS.exe"
Name: "{group}\Counter-Strike"; Filename: "{app}\Run_CS.exe"; WorkingDir: "{app}"; IconFilename: "{app}\Run_CS.exe"
Name: "{group}\Удалить игру"; Filename: "{uninstallexe}"; IconFilename: "{uninstallexe}"