Проблема с сервером

[supreme1337]

Всем привет. нужна ваша помощь, не запускается сервер..
В старт бате прописал: start /MIN/HIGH srcds.exe -console -game cstrike -noipx +map de_dust2 -maxplayers 16 -rcon_password ""
http://joxi.ru/file/full/f94bae9bb8405a ... E3ODgiO30/
Может где-то допустил ошибку?!
Кто сможет помочь, кину пару баксов на пиво

Добавлено спустя 23 минуты 46 секунд:
Установил только sourcemod и metamod..(windows)
И настроил админку

[weinstreizeR]

Почитай, пригодится.

[supreme1337]

Почитай, пригодится.

проблема в батнике?

[weinstreizeR]

Скорее всего да, не хватает некоторых обязательных команд запуска в консольном режиме.

[supreme1337]

Скорее всего да, не хватает некоторых обязятаельных команд запуска в консольном режиме.

Если не затруднит, кинь пожалуйста в личку пример правильного батника

[warloock]

Всем привет. нужна ваша помощь, не запускается сервер..
В старт бате прописал: start /MIN/HIGH srcds.exe -console -game cstrike -noipx +map de_dust2 -maxplayers 16 -rcon_password ""
http://joxi.ru/file/full/f94bae9bb8405a ... E3ODgiO30/
Может где-то допустил ошибку?!
Кто сможет помочь, кину пару баксов на пиво

Добавлено спустя 23 минуты 46 секунд:
Установил только sourcemod и metamod..(windows)
И настроил админку

В строке g:\Server\orangebox\srcds.exe -console -game cstrike -maxplayers 16 +fps_max 600 -port 27015 +map de_dust2 -tickrate 66
измени свой путь к файлу srcds.exe

SRCDS Guardian 3.bat

Код: Выделить всё

::=======================::
::  SRCDS Guardian 3.0   ::
::         Mooga         ::
::       SRCDS.com       ::
::=======================::

::=========================================================::
:: Thanks To Black-Sky & Drocona for making SRCDS Guardian ::
:: This script is open source.  Feel free to edit at will. ::
::                                                         ::
:: This script was writen for the use of the srcds.com     ::
:: online community.  If you are interested in running a   ::
:: Source Dedicated Server or need help, drop by our       ::
:: forums at... http://forums.srcds.com                    ::
::=========================================================::

::=======================::
::  SET YOUR VARIABLES!  ::
::=======================::

::=======================::
::  Window and Log name  ::
::  Replace "My Server"  ::
::=======================::
set servername=My Server

::=======================::
::   Your start command  ::
::    Replace after =    ::
::=======================::
set runcmd=g:\Server\orangebox\srcds.exe -console -game cstrike -maxplayers 16 +fps_max 600 -port 27015 +map de_dust2 -tickrate 66

::=======================::
::   End of variables    ::
::=======================::

:: This will keep the window clean and easy to read
@echo off

:: Sets the title of the window
title SRCDS Guardian 3.0   %servername%

:: Clears the window incase there is anything there
cls

:: Prints to the window what we are doing
echo SRCDS Guardian 3.0 has been started!
echo.
echo *************************************************************************
echo To close the server, close this window and type exit in the server window
echo *************************************************************************
echo.
echo.
echo %servername% is now starting...
>> "%servername%.log" echo.
>> "%servername%.log" echo.
>> "%servername%.log" echo (%date%)(%time%) SRCDS Guardian 3.0 has been started!
>> "%servername%.log" echo (%date%)(%time%) %servername% is now starting...

:: This is a return point in case the server crashes or is closed
:restart

echo.
echo (%date%)(%time%) %servername% is now ONLINE
echo Watching %servername% for crashes...
>> "%servername%.log" echo.
>> "%servername%.log" echo (%date%)(%time%) %servername% is now ONLINE
>> "%servername%.log" echo (%date%)(%time%) Watching %servername% for crashes...

::Start the actual server
start /wait %runcmd%

echo.
echo (%date%)(%time%) Crash or Close detected!
echo %servername% is now restarting...
>> "%servername%.log" echo.
>> "%servername%.log" echo (%date%)(%time%) Crash or Close detected!
>> "%servername%.log" echo (%date%)(%time%) %servername% is now restarting...

::Server crashed or closed, so we point it to the return point to start the server again
goto restart

[Coyote]

А помойму SDKTOOLS старой версии или конфликтует с чем-то, либо сурсмод старой версии. А ты откуда сурсмод брал?

[supreme1337]

Со старой проблемой разобрался, теперь проблема sourcemod'om, какой снапшотс ставить http://www.sourcemod.net/snapshots.php ?
Я поставил 1.5, development branch(2-windows)/т.е 1.5.0-hg3695.zip, но он не работает!

[weinstreizeR]

Зачем Dev branch, если есть Stable branch?