Patch Extractor

[maldersoft]

Программа предназначена для поиска и извлечения (в отдельную папку) обновленных файлов после обновления \ установки патча. (например стим обновления).
Отличается очень высокой производительностью, проверка более чем 15,000 файлов в секунду.

Использование
1) Открываем программу, выбираем корневую папку в которой будут обновляться файлы (например папку в стиме с L4D2), жмем кнопку "Сбор информации о файлах"
2) Оставляем программу открытой, обновляем свою игру\программу\итд стандартным способом(например запускаем стим)
3) Возвращаемся в программу и жмем кнопку "Сканирование патча"
4) Выбираем папку куда хотим выгрузить файлы обновления и жмем "Выгрузить".

Скачать программу
Программа
Исходник (Delphi)

[SAS123]

Может кому пригодится, есть VBS-скрипт, который копирует файлы с датой создания позже заданной:

VBScript

Код: Выделить всё

InitialFolder = "D:\css_setti" ' каталог, откуда копируем
TargetFolder = "D:\patch" ' каталог, куда копируем
ControlDate = CDate("18.10.2010") ' контрольная дата (копируем файлы с датой создания позже этой)
'====================================================================
On Error Resume Next
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShellApp = CreateObject("Shell.Application")
LogPath = objFSO.GetParentFolderName(WScript.ScriptFullName)
Set LogStream = objFSO.OpenTextFile(LogPath & "\CopyLog.log", 8, True)
LogStream.WriteLine "Начало копирования " & Now()

CopyFiles InitialFolder
LogStream.WriteLine "Конец копирования: " & Now()
LogStream.Close

' процедура рекурсивно перебирает файлы в каталоге
Sub CopyFiles(FolderPath)
    On Error Resume Next
    Set objFolderItems = objShellApp.NameSpace(FolderPath).Items()
    For Each objFolderItem In objFolderItems
        If objFolderItem.IsFolder And LCase(Right(objFolderItem.Name, 4)) <> ".zip" Then
            CopyFiles objFolderItem.Path
        Else
            Set objFile = objFSO.GetFile(objFolderItem.Path)
            If objFile.DateCreated > ControlDate Then
                CopyFile objFolderItem.Path
            End If
        End If
    Next
End Sub

' процедура копирует файл
Sub CopyFile(FilePath)
    On Error Resume Next
    SubPath = Mid(FilePath, Len(InitialFolder) + 1)
    TargetPath = TargetFolder & SubPath
    FolderPath = objFSO.GetParentFolderName(TargetPath)
    If Not objFSO.FolderExists(FolderPath) Then
        CreateFolder FolderPath
    End If
    ' если у файла назначения есть атрибут ReadOnly, снимаем его
    If objFSO.FileExists(TargetPath) Then
        Set objFile = objFSO.GetFile(TargetPath)
        If objFile.Attributes And 1 Then
            objFile.Attributes = objFile.Attributes - 1
        End If
    End If
    objFSO.CopyFile FilePath, TargetPath, True
    If Err.Number <> 0 Then
        LogStream.WriteLine
        LogStream.WriteLine FilePath
        LogStream.WriteLine Err.Description
        LogStream.WriteLine
        Err.Clear
    Else
        LogStream.WriteLine TargetPath
    End If
End Sub

' процедура создаёт каталог
Sub CreateFolder (FolderPath)
    On Error Resume Next
    ParentFolder = objFSO.GetParentFolderName(FolderPath)
    If Not objFSO.FolderExists(ParentFolder) Then
        CreateFolder ParentFolder
    End If
    objFSO.CreateFolder FolderPath
End Sub

Есть еще утилита FileCompare от rAzoR, сравнивает директории, создает файл-листы и т.п.
Самая интересная OneClickCacheUpdater, которая умеет сравнивать gcf-ки до и после обновления и обновленные файлы распаковывать в отдельную папку.

[MOZGIII]

maldersoft
Отлично, полезная вещица, спасибо)
Кинь на форму Win32 Manifest или как-то так он называется для красивости кнопочек мб?

[NiGHt-LEshiY]

Это что, diff?

[MOZGIII]

NiGHt-LEshiY
Угу, только простой как 2 пальца, такой можно и нубу дать поюзать - разберётся.